next up previous
Next: Existence of Solutions Up: The Art of Phugoid Previous: The Phugoid model

What do solutions look like?

Now that we have some equations in hand, our first goal is to understand what the solutions look like. Note that the equations are nonlinear, and we cannot hope to find explicit formulae for the solutions-- they don't exist except in very special cases.

Let's deal with the easiest case first: pretend that drag doesn't exist and set R = 0. Does this help?

The equations become

$\displaystyle {\frac{dv}{dt}}$ = - sin$\displaystyle \theta$                        $\displaystyle {\frac{d\theta}{dt}}$ = $\displaystyle {\frac{v^2 - \cos\theta}{v}}$

Now, let's see what we can say about the solutions to this equation. First, notice that there must be many solutions: Any choice of initial conditions $ \theta$(0) = $ \theta_{0}^{}$, v(0) = v0 gives rise to a different solution. (Informally, if the glider starts with a different initial angle and/or velocity, it will fly along a different path. If we say it this way, it seems so obvious we shouldn't need to say it at all.) Can we find any solutions at all?

There is one very easy solution to find. Notice that if we can find a choice of $ \theta$ and v so that $ {\frac{dv}{dt}}$ = 0 = $ {\frac{d\theta}{dt}}$, then since their derivatives are zero, v(t) and $ \theta$(t) must be constant functions. But solving this is simple:

0 = - sin$\displaystyle \theta$                0 = $\displaystyle {\frac{v^2 - \cos\theta}{v}}$

is easily seen to be true when $ \theta$ = 0 and v = 1. In fact, $ \theta$ can be any multiple of 2$ \pi$. So we have found the special solution

v(t) $\displaystyle \equiv$ 1                        $\displaystyle \theta$(t) $\displaystyle \equiv$ 0.

This is a glider which always flies level, with a constant velocity of 1.

What about other solutions? Now we must work harder. There is no hope to find a general analytic expression for v(t) and $ \theta$(t), but that does not mean all is lost. We can get an idea of how other solutions behave by thinking about what it means to have a solution $ \varphi$(t) = $ \left[\vphantom{ \theta(t), v(t) }\right.$$ \theta$(t), v(t)$ \left.\vphantom{ \theta(t), v(t) }\right]$.

First, notice that such a solution $ \varphi$ can be thought of as a parametric curve in the ($ \theta$, v)-plane which passes through the point $ \varphi$(0) = [$ \theta_{0}^{}$, v0]. At any point along this parametric curve, we can calculate its derivative:

$\displaystyle \varphi{^\prime}$(t) = $\displaystyle \left[\vphantom{ \frac{d}{dt}\theta(t), \frac{d}{dt}v(t) }\right.$$\displaystyle {\frac{d}{dt}}$$\displaystyle \theta$(t),$\displaystyle {\frac{d}{dt}}$v(t)$\displaystyle \left.\vphantom{ \frac{d}{dt}\theta(t), \frac{d}{dt}v(t) }\right]$ = $\displaystyle \left[\vphantom{ \dot{\theta}(t), \dot{v}(t) }\right.$$\displaystyle \dot{\theta}$(t),$\displaystyle \dot{v}$(t)$\displaystyle \left.\vphantom{ \dot{\theta}(t), \dot{v}(t) }\right]$.

But we started out with expressions for $ \dot{\theta}$ and $ \dot{v}$: our original differential equation. Because our differential equations only involve t implicitly via $ \theta$ and v (the system is autonomous), we need only know the values of $ \theta$ and v to know the tangent vector to any solution curve passing through that point.

We can get an idea of how the solutions behave by making a picture of the vector field corresponding to this: At each value for the pair ($ \theta$, v), we draw the vector $ \langle$$ \dot{\theta}$,$ \dot{v}$$ \rangle$, which only depends on ($ \theta$, v).

To get maple to do this, we can use the fieldplot command. Because the arrows in the fieldplot show not only direction but also relative magnitude, we shouldn't get too close to the v = 0 axis or they will overwhelm the smaller arrows for which occur for larger v.

  plots[fieldplot]( [ (v^2 - cos(theta))/v, -sin(theta) ], 
                    theta=-Pi..Pi, v=0.2..3, arrows=slim);

\begin{mfigure}\centerline{ \psfig{figure=glider01.eps,height=2.5in}}\end{mfigure}

We can certainly see that near the constant solution {$ \theta$ = 0, v = 1}, nearby solutions rotate around it in a clockwise manner. This ``rotation'' in the $ \theta$ - v coordinates corresponds to a flight path which wobbles: the nose angle alternately increases and decreases, as does the velocity. For v large, it seems that the solutions move from left to right-- $ \theta$ constantly increases, which means that the glider is always increasing its nose angle. This means it is doing loops.

We can also use the DEplot command from Maple's DEtools package to produce a direction field. The direction field is obtained from the vector field by rescaling all nonzero vectors to be of unit length. Sometimes discarding the extra information makes it easier to see what is happening. In addition, DEplot has other very useful options, and will be one of our primary tools throughout this chapter.

For convenience, we will name our system of differential equations as phug, so that we needn't keep retyping them.

  phug := [ diff(theta(t),t) =  (v(t)^2 - cos(theta(t)))/v(t),
            diff(v(t),t)     =  -sin(theta(t)) - R*v(t)^2 ];

\mathit{phug} := [{\frac {\partial }{\par...
R := 0

  DEplot( phug, [theta(t), v(t)], t=0..1, theta=-Pi..Pi, v=0.01..3);

\begin{mfigure}\centerline{ \psfig{figure=glider02.eps,height=2.5in}}\end{mfigure}

We can also ask maple to plot a number of solutions corresponding to several initial conditions. Rather than typing in 11 initial conditions, we can use seq to generate them. We tell maple that the solution curves should be black, because otherwise it uses a sickly yellow. If we had wanted each solution curve to be a different color, we could use something like linecolor=[seq(COLOR(HUE,i/10),i=0..10)].

  DEplot( phug, [theta(t), v(t)], t=0..5, 
          [seq([theta(0)=0, v(0)=1+0.2*i], i=0..10)],
          theta=-Pi..3*Pi, v=0.01..3, linecolor=black );

\begin{mfigure}\centerline{ \psfig{figure=glider03.eps,height=2.5in}}\end{mfigure}

The above figure confirms our earlier impressions about the ``wobbling'' and ``looping'' solutions. We'll see how to get Maple to demonstrate this more explicitly in section 5, where we will plot the path of the glider through space (i.e., in x-y coordinates).

Just to see how things differ if we make R nonzero, let's change R and get Maple to show us what happens. We need to adjust the stepsize to get a reasonable accuracy; what precisely this does is described in the next section.

  DEplot( phug, [theta(t), v(t)], t=0..5, 
          [seq([theta(0)=0, v(0)=1+0.2*i], i=0..10)],
          theta=-Pi..3*Pi, v=0.01..3, linecolor=black, stepsize=0.1 );

R : = .1

\begin{mfigure}\centerline{ \psfig{figure=glider03a.eps,height=2.5in}}\end{mfigure}

  DEplot( phug, [theta(t), v(t)], t=0..5, 
          [seq([theta(0)=0, v(0)=1+0.2*i], i=0..10)],
          theta=-Pi..3*Pi, v=0.01..3, linecolor=black,stepsize=0.1 );

R : = 3;

\begin{mfigure}\centerline{ \psfig{figure=glider03b.eps,height=2.5in}}\end{mfigure}

The behavior of the glider appears to be dramatically affected by the drag parameter R. One of our main goals in this chapter will be to classify the types of solutions that are possible as a function of the drag parameter R.

next up previous
Next: Existence of Solutions Up: The Art of Phugoid Previous: The Phugoid model

Translated from LaTeX by Scott Sutherland