SUNY at Stony Brook -- Mathematics Department

Slope fields on the Texas Instruments TI-85 Calculator

This program draws a 96-element (12 x 8) slope field in the rectangle [xMin,xMax]x[yMin,yMax]. The slopes are given by the function of x and y stored as y1.

General: To type an upper case letter, press ALPHA key, followed by the letter. To type a lower case letter, press 2nd key, then ALPHA key, followed by the letter. To enter the program into the calculator, press PRGM, then F2 (which selects the EDIT box), then the program name (e.g. SLOPE) followed by ENTER. The calculator will shift to a new line and display the colon : which must start each instruction. After typing each instruction, press the ENTER key. When navigating menus, use EXIT to go back.
This program is more elaborate than the others because it must link the computational and graphing operations of the calculator.

COMMAND: 		Explanation and keying instructions:
:FnOff			Inactivates function graphing. GRAPH,	
:ClDrw			Clears the screen. GRAPH,MORE,F2,MORE,F4.
:Prompt xMin,xMax,yMin,
yMax			Prompts for input of screen parameters. Prompt is
			F3,F2. xMin, etc. are on the GRAPH,F2 menu.
:7(xMax - xMin)/83->H	Calculates horizontal step-size. - is to the
			right of 6, / is the division key, which is under 
			the ^ key, -> is STO. 
:7(yMax - yMin)/55->K	Calculates vertical step-size.	
:1/(0.4H)^2->A		The numbers A and B are used in calculating
:1/(0.4K)^2->B		the how long the lines should be.
:xMin+0.5H->x		Calculates position of lower left-hand slope line.
:yMin+0.5K->Z		Use x-VAR to get x.
:1->I			Initialize I: counts columns.
:Lbl P			Labels this program location. Lbl is F4,MORE,F4
:1->J			Initialize J: counts rows.
:Z->y			Initialize y for the current column. Use lower
			case y if you use l.c. y in the expression y1.
:Lbl Q			Labels this program location.
:y1->T			Program applies expression stored as y1 to compute
			the current slope. To get y1, type y and then 1.
:1/sqrt(A+B*T^2)->C	sqrt is the square-root (2nd x-squared, to the
			left of 7). * is the times key (next to 9). These
:T*C->S			two instructions calculate the horizontal and
			vertical extent of the line segment to be drawn.
:x->U			Store current x,y values as U and V.
:Line(U-C,V-S,U+C,V+S)	Draws a line segment through (x,y). The comma is 
			the key  to the left of the 4 key.
:V+K->y			Increment y.
:IS>(J,8)		Add 1 to J and test. If less than or equal 8,
			go to the next instruction (i.e. proceed up
			the column). If greater, skip next instruction.
			For IS>(, press F4 (chooses CTL menu), MORE,
			MORE, F1.
:Goto Q
:U+H->x			Increment x (i.e. move to next column).
:IS>(I,12)		Test if all columns are done.
:Goto P

Ending: After pressing the ENTER key for the last command, press the EXIT key.

Running the program: First enter the function giving the slope: Press GRAPH, F1, then type it in as a function of the two variables x (use x-VAR) and y (use same case (upper/lower) as in program. (e.g. x+y). Then EXIT,EXIT to return to home screen. Now PRGM, F1, then the F-key under the word SLOPE in the screen, then ENTER. Enter numbers at the question mark (?) prompts. After graph is drawn, to exit press EXIT key.

Check: For y1 = -x/y get circles centered at the origin. The circles will be round if your screen parameters have the correct aspect ratio.
Check: For y1 = x+y and window [-3,3]x[-2,2], calculator screen should have the image shown on the right. (Image generated with a SHARP EL-9300C; TI-85 has finer resolution.)

Anthony Phillips
Math Dept SUNY Stony Brook
September 12 1997